FB40 MAIN P01 : P02 main automatic program (FDR)

[hit  <- on your browser to return]

Netzwerk 1: P02 Initialisation

IF "M02 Init" OR NOT "M00 OB1 FirstCycle" THEN

    #STEP_BITS := 0;

    IF "M02 Init" THEN

        "M02 MD40" := "M02 MD44" := 0;

        "M02 HomPosRun" := TRUE;

        "DatOfMod".P02.CrntModule := 102;

    END_IF;

END_IF;

Netzwerk 2: P02 SET execute home position

IF "M02 HomPosRun" AND #SET.S.step0 THEN

    #SET.S.steps := TRUE;

ELSIF NOT "M02 HomPosRun" OR "HMI KEY".SYS.GLB.F8_Stop OR "HMI KEY".P02.GLB.F8_Stop THEN

    #SET.S.steps := "M02 HomPosRun" := FALSE;

END_IF;

#SET.S.steph := "M02 FLT ModuleStpSR";

#SET();

Netzwerk 3: P02 SEQ1 start, stop, hold

#SEQ1.S.steph := NOT "M00 AutoCmpltMa run" AND "M02 SEQ1 Start";

#SEQ1.S.steps := NOT "M02 HomPosRun" AND "M02 SEQ1 Start";

IF "M00 CmpltMaOFF Imp" THEN

    #SEQ1.S.stepin := FALSE;

END_IF;

#SEQ1();

Netzwerk 4: P02 FLT faults monitoring

##FLT(FLT_MODULE := "M02 FLT ModuleIS");

Netzwerk 5: P02 STEP.SEQ1_Start

IF "M00 CmpltMaRun Imp" AND ("M00 AutoCmpltMa run" XOR "M00 InchCmpltMa run") THEN

    #STEP.SEQ1_Start := TRUE;

    RETURN;

ELSIF #STEP.SEQ1_Start THEN

    IF NOT ("M02 HomPosRun" OR "M02 SEQ1 Active") THEN

        "M02 SEQ1 Start" := TRUE;

    ELSIF "M02 SEQ1 Active" THEN

        #MoDa.RunTimeCntr_seq1 := 0;

        #STEP_BITS := 0;

        #STEP.SEQ1_Running := TRUE;

    END_IF;

END_IF;

Netzwerk 6: P02 STEP.SEQ1_Running

IF #STEP.SEQ1_Running THEN

    IF "M02 SEQ1 Done" THEN

        "M02 SEQ1 Start" := FALSE;

        #STEP_BITS := 0;

        #STEP.SEQ1_Done := TRUE;

        RETURN;

    END_IF;

END_IF;

Netzwerk 7: P02 STEP.Done

IF #STEP.SEQ1_Done THEN

    "M02 SEQ1 Done" := FALSE;

    #STEP_BITS := 0;

    #STEP.SEQ1_Write := TRUE;

    // Save actual data   

    "DatOfMod".P02.STS.RunTimeCntr_seq1 := #MoDa.RunTimeCntr_seq1;

    "DatOfMod".P02.STS.WPC_ok := "M02 SEQ1 DoWP1" AND "M02 SEQ1 WP1 DnOK";

    "DatOfMod".P02.STS.CrntWP_ok := "M02 SEQ1 WP1 DnOK" AND NOT "M02 SEQ1 WP1 DnNOK";

    "DatOfMod".P02.TrgtModule := 103;

    // If necessary, changing drive direction to module 104   

    IF NOT "DatOfMod".P02.STS.CrntWP_ok THEN

        "DatOfMod".P02.TrgtModule := 104;

    END_IF;

    "DatOfPLC".P02 := "DatOfMod".P02; // BLKMOV

END_IF;

Netzwerk 8: P02 STEP.Write

IF #STEP.SEQ1_Write THEN

    "M02 SEQ1 WP1 DnOK" := FALSE;

    "M02 TCP/IP Wrt start" := TRUE;

    IF "M02 TCP/IP Wrt done" THEN

        "M02 TCP/IP Wrt start" := "M02 TCP/IP Wrt done" := FALSE;

        #STEP_BITS := 0;

        RETURN;

    END_IF;

END_IF;

Netzwerk 9: P02 Run-Time

"M02 Enabled" := "M00 AutoCmpltMa run" AND NOT "M02 FLT ModuleStpSR";

IF #STEP.SEQ1_Running THEN

    IF "M00 Imp 10Hz" AND "M02 Enabled" THEN

        #MoDa.RunTimeCntr_seq1 := #MoDa.RunTimeCntr_seq1 + 1;

    END_IF;

ELSE

    IF NOT "M02 Active" AND "M00 AutoCmpltMa run" THEN

        #STEP.SEQ1_Start := TRUE;

    END_IF;

END_IF;

Netzwerk 10: P02 SEQ1 active

"M02 Active" :=

#STEP.SEQ1_Start AND "M02 SEQ1 Active"

OR #STEP.SEQ1_Running

OR #STEP.SEQ1_Done

OR #STEP.SEQ1_Write;

Netzwerk 11: P02 Assing signal  

IF "M02 FLT ModuleIS" THEN

    "M02 FLT ModuleStpSR" := true;

END_IF;

IF "M02 FLT ModuleStpSR" AND NOT "M02 FLT ModuleStpACK" THEN

    IF "M00 FLT CmpltMaACK Imp" THEN

        "M02 FLT ModuleStpACK" := true;

    END_IF;

ELSIF NOT "M02 FLT ModuleIS" AND "M02 FLT ModuleStpACK" THEN

    "M02 FLT ModuleStpSR" := "M02 FLT ModuleStpACK" := FALSE;

END_IF;