Home

Erfahrung

Referenzen

Sondermaschinen

MSR-Maschinen

SPS-Programmierung

Visualisierung HMI

Elektro CAD

Leistungsprofil

Personalia

SW-Development

Dokumentation

Impressum & DSGVO

FB38 MAM P01 : Manual operation

Network 1: S120M Master Sheet Metal Infeed - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.EntirePlant_Run_Imp THEN

        #S120M.ManualVelocity_1 := "DI OUT P01".S120M.DRV.Support.SetVelo; // m/min

    END_IF;

    "DI OUT P01".S120M.DRV.Support.SetVelo := #S120M.ManualVelocity_1;

        // MoveJog (toggle function)

    IF "HMI KEY".P01.S120M.F19_Jog_fast_WP AND NOT #S120M.Jog_fast_WP_REg THEN

        #S120M.CmdExe_slow_fast_WP := NOT #S120M.CmdExe_slow_fast_WP AND "HMI KEY".P01.S120M.F12_Enable_WP;

        #S120M.CmdExe_slow_fast_HP := FALSE;

    ELSIF "HMI KEY".P01.S120M.F20_Jog_fast_HP AND NOT #S120M.Jog_fast_HP_REg THEN

        #S120M.CmdExe_slow_fast_HP := NOT #S120M.CmdExe_slow_fast_HP AND "HMI KEY".P01.S120M.F11_Enable_HP;

        #S120M.CmdExe_slow_fast_WP := FALSE;

    END_IF;

    #S120M.Jog_fast_WP_REg := "HMI KEY".P01.S120M.F19_Jog_fast_WP;

    #S120M.Jog_fast_HP_REg := "HMI KEY".P01.S120M.F20_Jog_fast_HP;

END_IF;

// Enable disable operation (Modulo active)

"HMI KEY".P01.S120M.F11_Enable_HP := "DI OUT P01".S120M.DRV.Support.InOperation AND NOT ("DI OUT P01".S120M.Common_FLT OR "DI MAIN P01".M00.FLT_ModuleFault_SR);

"HMI KEY".P01.S120M.F12_Enable_WP := "DI OUT P01".S120M.DRV.Support.InOperation AND NOT ("DI OUT P01".S120M.Common_FLT OR "DI MAIN P01".M00.FLT_ModuleFault_SR);

// HALT moving

IF "DI OUT P01".S120M.HALT_01 OR #S120M.ManualVelocity_1 = 0.0 THEN

    #S120M.CmdExe_slow_fast_HP := #S120M.CmdExe_slow_fast_WP := FALSE;

END_IF;

Network 2: S120S1 Slave Punch-Cutter - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.EntirePlant_Run_Imp THEN

        #S120S1.ManualVelocity_1 := "DI OUT P01".S120S1.DRV.Support.SetVelo; // m/min

    END_IF;

    // MoveJog

    "DI OUT P01".S120S1.DRV.Support.SetVelo := #S120S1.ManualVelocity_1;

    #S120S1.CmdExe_slow_fast_WP := "HMI KEY".P01.S120S1.F3_Jog_slow_WP AND "HMI KEY".P01.S120S1.F12_Enable_WP AND NOT "HMI KEY".P01.S120S1.F21_HALT;

    #S120S1.CmdExe_slow_fast_HP := "HMI KEY".P01.S120S1.F4_Jog_slow_HP AND "HMI KEY".P01.S120S1."F11_Enable_HP" AND NOT "HMI KEY".P01.S120S1.F21_HALT;

END_IF;

// Enable disable operation (Modulo active)

"HMI KEY".P01.S120S1.F11_Enable_HP := "DI OUT P01".S120S1.DRV.Support.InOperation AND NOT "DI OUT P01".S120S1.Common_FLT;

"HMI KEY".P01.S120S1.F12_Enable_WP := "DI OUT P01".S120S1.DRV.Support.InOperation AND NOT "DI OUT P01".S120S1.Common_FLT;

Network 3: S120S2 Slave Upper Stamping-Die - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.EntirePlant_Run_Imp THEN

        #S120S2.ManualVelocity_1 := "DI OUT P01".S120S2.DRV.Support.SetVelo; // m/min

    END_IF;

    // MoveJog

    "DI OUT P01".S120S2.DRV.Support.SetVelo := #S120S2.ManualVelocity_1;

    #S120S2.CmdExe_slow_fast_WP := "HMI KEY".P01.S120S2.F3_Jog_slow_WP AND "HMI KEY".P01.S120S2.F12_Enable_WP AND NOT "HMI KEY".P01.S120S2.F21_HALT;

    #S120S2.CmdExe_slow_fast_HP := "HMI KEY".P01.S120S2.F4_Jog_slow_HP AND "HMI KEY".P01.S120S2."F11_Enable_HP" AND NOT "HMI KEY".P01.S120S2.F21_HALT;

END_IF;

// Enable disable operation (Modulo active)

"HMI KEY".P01.S120S2.F11_Enable_HP := "DI OUT P01".S120S2.DRV.Support.InOperation AND NOT "DI OUT P01".S120S2.Common_FLT;

"HMI KEY".P01.S120S2.F12_Enable_WP := "DI OUT P01".S120S2.DRV.Support.InOperation AND NOT "DI OUT P01".S120S2.Common_FLT;

Network 4: V100 Sheet Metal Cutter - enable

"HMI KEY".P01.V100.F12_Enable_WP := NOT "DI OUT P01".V100.Common_FLT;

Network 5: CAM_DISC_S1 Control - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.EntirePlant_Run_Imp THEN

        #CAM_DISC_S1.ManualVelocity_1 := "DI OUT P01".CAM_DISC_S1.CAM.MC_CamIn.Velocity;

    END_IF;

    // Assign velocity manual mode

    IF "DI OUT P01".CAM_DISC_S1.CAM.MC_CamIn.SyncProfileReference = 0 THEN

        "DI OUT P01".CAM_DISC_S1.CAM.MC_CamIn.Velocity := #CAM_DISC_S1.ManualVelocity_1;

    ELSE

        "DI OUT P01".CAM_DISC_S1.CAM.MC_CamIn.Velocity := #CAM_DISC_S1.ManualVelocity_1 := -1.0;

    END_IF;

END_IF;

// Execute start

#CAM_DISC_S1.CmdExe_slow_WP := "HMI KEY".P01.CAM_DISC_S1.F10_Execute AND "DI OUT P01".S120M.DRV.Support.LampON AND "DI OUT P01".S120M.DRV.Support.InPos;

// Enabling

"HMI KEY".P01.CAM_DISC_S1.F11_Enable_HP := NOT "DI OUT P01".CAM_DISC_S1.CAM.MC_CamIn.Busy AND "HMI KEY".P01.CAM_DISC_S1.F12_Enable_WP;

"HMI KEY".P01.CAM_DISC_S1.F12_Enable_WP := NOT ("DI OUT P01".CAM_DISC_S1.Common_FLT OR "DI OUT P01".S120S1.Common_FLT);

Network 6: CAM_DISC_S2 Control - enable

IF #ST_MANU AND NOT #SUPPORT_SEQ THEN

    IF "DI MAIN GLB".M00.EntirePlant_Run_Imp THEN

        #CAM_DISC_S2.ManualVelocity_1 := "DI OUT P01".CAM_DISC_S2.CAM.MC_CamIn.Velocity;

    END_IF;

    // Assign velocity manual mode

    IF "DI OUT P01".CAM_DISC_S2.CAM.MC_CamIn.SyncProfileReference = 0 THEN

        "DI OUT P01".CAM_DISC_S2.CAM.MC_CamIn.Velocity := #CAM_DISC_S2.ManualVelocity_1;

    ELSE

        "DI OUT P01".CAM_DISC_S2.CAM.MC_CamIn.Velocity := #CAM_DISC_S2.ManualVelocity_1 := -1.0;

    END_IF;

END_IF;

// Execute start

#CAM_DISC_S2.CmdExe_slow_WP := "HMI KEY".P01.CAM_DISC_S2.F10_Execute AND "DI OUT P01".S120M.DRV.Support.LampON AND "DI OUT P01".S120M.DRV.Support.InPos;

// Enabling

"HMI KEY".P01.CAM_DISC_S2.F11_Enable_HP := NOT "DI OUT P01".CAM_DISC_S2.CAM.MC_CamIn.Busy AND "HMI KEY".P01.CAM_DISC_S2.F12_Enable_WP;

"HMI KEY".P01.CAM_DISC_S2.F12_Enable_WP := NOT ("DI OUT P01".CAM_DISC_S2.Common_FLT OR "DI OUT P01".S120S2.Common_FLT);

Network 7: Monitoring manual operation ***

IF NOT #ST_MANU THEN

    RETURN;

ELSIF #MODULE_HP AND NOT #Support.HomPos_REg THEN

    "DI MAIN P01".M00.Initialization := TRUE;

END_IF;

#Support.HomPos_REg := #MODULE_HP;

"DI MAIN P01".M00.TOF_EntireModule_STOP_Pulse(IN := NOT #SUPPORT_SEQ AND #Support.HomPos_FEg,

                                              PT := t#500ms);

#Support.HomPos_FEg := #SUPPORT_SEQ;

IF #SUPPORT_SEQ THEN

    RETURN;

END_IF;

Network 8: V100 Sheet Metal Cutter - execute

"DI OUT P01".V100.VLV_O.CmdExe_WP := "HMI KEY".P01.V100.F12_Enable_WP

AND NOT "HMI KEY".P01.V100.F1_HP AND ("HMI KEY".P01.V100.F2_WP OR "DI OUT P01".V100.FB_WP);

Network 9: CAM_DISC_S1 Control - execute

"DI OUT P01".CAM_DISC_S1.CAM.MC_MeasuringInput.Execute := "DI OUT P01".CAM_DISC_S1.CAM.Support.ReadyTo_ReStart AND "HMI KEY".P01.CAM_DISC_S1.F11_Enable_HP

AND #CAM_DISC_S1.CmdExe_slow_WP;

Network 10: CAM_DISC_S2 Control - execute

"DI OUT P01".CAM_DISC_S2.CAM.MC_MeasuringInput.Execute := "DI OUT P01".CAM_DISC_S2.CAM.Support.ReadyTo_ReStart AND "HMI KEY".P01.CAM_DISC_S2.F11_Enable_HP

AND #CAM_DISC_S2.CmdExe_slow_WP;